怎样用代码隐藏、最大化、最小化ACCESS的主窗口
该函数能用来完全隐藏 Access 窗口并将你自己的窗体显示在桌面上。在弹出式窗体的 Open 事件中使用 SW_HIDE 参数调用fSetACCESSWindow 函数实现。
注意：如果你隐藏了 Access 主窗口，要确定你有良好的出错处理。因为主窗口隐藏后，一旦引发错误，并出错提示窗口上点击了“结束”按钮，这样不会使 Access 主窗口可见，并退出你自己的窗体。推荐你在你的错误处理程序中使用 SW_SHOWNORMAL 参数调用 fSetAccessWindow 函数来显示 ACCESS 主窗口。
如果由于别的原因，ACCESS 主窗口不能显示，那么你将只能从任务栏中关闭你的 mdb，在 Win 9x 中使用 Control-Alt-Delete 来结束任务，在 Win NT 、2000 或 XP 中，可以右键单击任务栏选择任务管理器来选择该 mdb 结束任务。
以下为引用的内容：
'************ 代码开始 **********
Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3
Private Declare Function apiShowWindow Lib "user32" _
Alias "ShowWindow" (ByVal hwnd As Long, _
ByVal nCmdShow As Long) As Long
Function fSetACCESSWindow(nCmdShow As Long)
' 使用举例
' 最大化 ACCESS 窗口
' ?fSetACCESSWindow(SW_SHOWMAXIMIZED)
' 最小化 ACCESS 窗口
' ?fSetACCESSWindow(SW_SHOWMINIMIZED)
' 隐藏 ACCESS 窗口
' ?fSetACCESSWindow(SW_HIDE)
' 正常显示 ACCESS 窗口
' ?fSetACCESSWindow(SW_SHOWNORMAL)
'
Dim loX As Long
Dim loFORM As FORM
On Error Resume Next
Set loFORM = Screen.ActiveFORM
If Err <> 0 Then ' 没有活动窗体 no ActiveFORM
If nCmdShow = SW_HIDE Then
MsgBox "除非屏幕上有一个窗口，否则不能隐藏 ACCESS 主窗口!" _
& vbcr & VBcr _
& "Cannot hide ACCESS unless " _
& "a FORM is on screen"
Else
loX = apiShowWindow(hWndACCESSApp, nCmdShow)
Err.Clear
End If
Else
If nCmdShow = SW_SHOWMINIMIZED And loFORM.Modal = True Then
MsgBox "不能由屏幕上的 " & (loFORM.Caption + " ") & "窗体最小化 ACCESS 主窗口!" _
& vbcr & VBcr _
& "Cannot minimize ACCESS with " _
& (loFORM.Caption + " ") _
& "FORM on screen"
ElseIf nCmdShow = SW_HIDE And loFORM.PopUp <> True Then
MsgBox "不能由屏幕上的 " & (loFORM.Caption + " ") & "窗体隐藏 ACCESS 主窗口!" _
& vbcr & VBcr _
& "Cannot hide ACCESS with " _
& (loFORM.Caption + " ") _
& "FORM on screen"
Else
loX = apiShowWindow(hWndACCESSApp, nCmdShow)
End If
End If
fSetACCESSWindow = (loX <> 0)
End Function
'************ 代码结束 **********